メインコンテンツまでスキップ

logoCorrectSize.png

Looks like this logo isn't being used anymore since we started using the new CSS to make our documentation look like our product UI.

Knowledge @ Adaptive Insights LLC, a Workday Company

従業員、給付単価の例

一般的に使用される福利厚生算定方式の詳細な例を示します。

401k(確定拠出年金)計算

401k計算では、たいていの会社は、人事費用の計画の際に給与比例パーセンテージ マッチの前提条件を作成しますが、最高年収額とのパーセンテージ マッチを行う会社もあります。

401k年金額給与比例パーセント

  • 次のグローバル前提条件科目を作成します。
前提条件名 前提条件コード 科目タイプ
401(k)給与比例マッチ 401K_FLAT_Match パーセント

数式

科目名 科目コード 科目タイプ 数式
401(k)従業員選挙 401kEmployeeElection モデル - 周期 - 通貨

ASSUM.401K_Flat_Match*
ROW.TaxableComp

最高給与を使った401kマッチ

  • 次のグローバル前提条件科目を作成します。
前提条件名 前提条件コード 科目タイプ 表示形式
401(k)最高給与 401K_Max 周期 - 平均 数値
401(k)最初のx%のうちの100% Match_100Perc 周期 - 平均 パーセント
401(k)次のx%のうちの50% Match_50Perc 周期 - 平均 パーセント
  • これらの科目が次の  [科目設定] になっていることを確認します。

    • 時間合計 = 合計値の平均
    • 実績のオーバーレイ = 科目の実績なし(計画データを表示)
  • 必要なモデル科目には次のものがあります。
科目名 科目コード 科目タイプ 表示形式
課税の対象となる報酬 TaxableComp モデル - 定期的 通貨

数式

科目名 科目コード 科目タイプ  

401(k)会社マッチ
100% - 累積

Comp_Match_100 モデル - 周期 - 通貨  

数式

IFF(month(this)=1,ROW.TaxableComp*ASSUM.Match_100Perc, ROW.Comp_Match_100[time=this-1] + ROW.TaxableComp *ASSUM.Match_100Perc)

 

401(k)会社マッチ
50% - 累積

Comp_Match_50 モデル - 周期 - 通貨

 

数式

IFF(month(this)=1,ROW.TaxableComp*DIVF(ASSUM.Match_50Perc,2), ROW.Comp_Match_50[time=this-1] + ROW.TaxableComp *DIVF(ASSUM.Match_50Perc,2))

401(k)会社マッチ
合計 - 累積
Comp_Match_Total モデル - 周期 - 通貨

 

数式

ROW.Comp_Match_100+ROW.Comp_Match_50

 

401k費用 401k_Expense モデル - 周期 - 通貨  

数式

IFF(ROW.Comp_Match_Total<=ASSUM.401k_Max, (ROW.TaxableComp*ASSUM.Match_100Perc)+(ROW.TaxableComp*divf(ASSUM.Match_50Perc,2)), IFF(ROW.Comp_Match_Total>ASSUM.401k_Max and ROW.Comp_Match_Total[time=this-1]<=ASSUM.401k_Max, ASSUM.401k_Max-ROW.Comp_Match_Total[time=this-1],0))

医療、歯科、視力の給付

たいていの会社は、医療、歯科、視覚用の給付を計画したいと考えています。それは、それぞれ別々のレートを管理/保守する能力をもった従業員の選挙に基づきます。’

給付属性のセットアップを開始するには、次の手順に従います。標準設定を保持します。[リスト属性] が選択されていることを確認します。ただし、[組織で使用]、[データ インポートは自動的に属性値を作成する]、[並べ替えを維持] は選択されていないことを確認します。

属性内で、次の属性値をセットアップします。

  1. 従業員のみ      
  2. 従業員 + 配偶者
  3. 従業員 + 子
  4. 従業員 + 家族

次のグローバル前提条件科目を作成します。

  • 全社(のみ)で使用可能なユーザー割り当てのキューブ シートをセットアップし、3つの標準キューブ科目を作成します。
科目名 科目コード 科目タイプ 表示形式
医療レート 医療 周期 通貨
歯科レート 歯科 周期 通貨
視覚レート 視覚 周期 通貨
  • これらの科目が次の  [科目設定] になっていることを確認します。

    • 時間合計 = 合計値の平均
    • 組織合計 = 合計値の空白なし平均
    • 実績のオーバーレイ = 科目の実績なし(計画データを表示)
    • 表示形式 = 通貨
    • データのプライバシー + 科目の値は、すべての組織で公開

キューブ科目をセットアップし終わったら、[給付] 属性をキューブ シートに追加します。

数式

必要な毎月のルックアップ テーブルは次のとおりです。 

科目名 科目コード 入力された値
福利厚生の対象 Benefits_Eligible 従業員タイプ - テキストセレクタ 関連するすべての組み合わせに1を読み込む

ここで従業員のモデルシートに次の算出科目を設定します。

科目名 科目コード 科目タイプ 数式
医療費 Medical_Expense モデル - 周期 - 通貨

ACCT.Beneft_Rates.Medical[level=Top Level(-), Benefit=this]*Row.Headcount*Row.Benefits_Eligible

歯科医療費 Dental_Expense モデル - 周期 - 通貨

ACCT.Beneft_Rates.Dental[level=Top Level(-), Benefit=this]*Row.Headcount*Row.Benefits_Eligible

眼科医療費 Vision_Expense モデル - 周期 - 通貨

ACCT.Beneft_Rates.Vision[level=Top Level(-),
Benefit=this]*Row.Headcount*Row.Benefits_Eligible

生命保険

企業の大半は、利益X ドル当たりの固定率で生命保険プランがあります。

  • 次のグローバル前提条件科目を作成します。
前提条件名 前提条件コード 科目タイプ
Life_Rate 生命保険率/利益$X当たり 数値
Life_per_Dollar 率に適用する$(当たり) 数値
Life_Multiplier 生命保険の乗数(年収) 数値
Life_Max_Benefit 生命保険最大利益 数値
  • これらの科目が次の  [科目設定] になっていることを確認します。

    • 時間合計 = 合計値の平均
    • 実績のオーバーレイ = 科目の実績なし(計画データを表示)

数式

前提条件名 前提条件コード 科目タイプ  
生命保険 Life_Insurance モデル - 周期 - 通貨  

数式

IFF(DIV(ASSUM.Life_Max_Benefit,ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate> DIV(((ROW.Headcount*ROW.Salary*ASSUM.Life_Multiplier)),ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate,DIV(((ROW.Headcount*ROW.Salary)*
ASSUM.Life_Multiplier),ASSUM.Life_per_Dollar)*
ASSUM.Life_Rate,div(ASSUM.Life_Max_Benefit,ASSUM.Life_per_Dollar)*ASSUM.Life_Rate)*
Row.Benefits_Eligible

長期/短期の障害(LTD/STD)

企業の大半は、$当たりの補償率に基づいて従業員の障害を補償します。 

  • 次のグローバル前提条件科目を作成します。
前提条件名 前提条件コード 科目タイプ 表示形式
$100当たりの補償率 LTD_RatePer100 周期 - 平均 数値
$10当たりの補償率 STD_RatePer10 周期 - 平均 数値
  • これらの科目が次の  [科目設定] になっていることを確認します。

    • 時間合計 = 合計値の平均
    • 実績のオーバーレイ = 科目の実績なし(計画データを表示)

数式

科目名 科目コード 科目タイプ 数式
LTD費用 LTD_Expense モデル - 周期 - 通貨

DIVF(ROW.Salary,100) * ASSUM.LTD_RatePer100 * Row.Benefits_Eligible

STD費用 STD_Expense モデル - 周期 - 通貨

DIVF(ROW.Salary,10) * ASSUM.STD_RatePer10 * Row.Benefits_Eligible

  • この記事は役に立ちましたか?